Move media stack to tofu

2026-02-09 23:10:53 +01:00
parent f20172f6a4
commit c258a1d09e
17 changed files with 1211 additions and 502 deletions
--- a/media/wizarr.tf
+++ b/media/wizarr.tf
@@ -0,0 +1,140 @@
+variable "wizarr" {
+  type = object({
+    app_name  = optional(string, "wizarr")
+    image     = string
+    version   = optional(string, "latest")
+    subdomain = optional(string, "wizarr")
+    port      = optional(number, 5690)
+  })
+}
+
+resource "kubernetes_service_v1" "wizarr" {
+  metadata {
+    name      = var.wizarr.app_name
+    namespace = kubernetes_namespace_v1.media.metadata[0].name
+  }
+
+  spec {
+    selector = {
+      app = var.wizarr.app_name
+    }
+    port {
+      port        = var.wizarr.port
+      target_port = var.wizarr.port
+    }
+  }
+}
+
+resource "kubernetes_ingress_v1" "wizarr" {
+  metadata {
+    name      = var.wizarr.app_name
+    namespace = kubernetes_namespace_v1.media.metadata[0].name
+
+    annotations = {
+      "cert-manager.io/cluster-issuer" = "letsencrypt"
+    }
+  }
+
+  spec {
+    tls {
+      hosts       = ["${var.wizarr.subdomain}.${var.domain}"]
+      secret_name = "${var.wizarr.app_name}-tls"
+    }
+
+    rule {
+      host = "${var.wizarr.subdomain}.${var.domain}"
+      http {
+        path {
+          path      = "/"
+          path_type = "Prefix"
+          backend {
+            service {
+              name = kubernetes_service_v1.wizarr.metadata[0].name
+              port {
+                number = var.wizarr.port
+              }
+            }
+          }
+        }
+      }
+    }
+  }
+}
+
+resource "kubernetes_persistent_volume_claim_v1" "wizarr-data" {
+  metadata {
+    name      = "${var.wizarr.app_name}-data"
+    namespace = kubernetes_namespace_v1.media.metadata[0].name
+  }
+
+  spec {
+    storage_class_name = "local-path"
+    access_modes       = ["ReadWriteOnce"]
+
+    resources {
+      requests = {
+        storage = "1Gi"
+      }
+    }
+  }
+}
+
+resource "kubernetes_deployment_v1" "wizarr" {
+  metadata {
+    name      = var.wizarr.app_name
+    namespace = kubernetes_namespace_v1.media.metadata[0].name
+    labels = {
+      app = var.wizarr.app_name
+    }
+  }
+
+  spec {
+    replicas = 1
+    selector {
+      match_labels = {
+        app = var.wizarr.app_name
+      }
+    }
+
+    template {
+      metadata {
+        labels = {
+          "app" = var.wizarr.app_name
+        }
+      }
+
+      spec {
+        container {
+          name              = var.wizarr.app_name
+          image             = "${var.wizarr.image}:${var.wizarr.version}"
+          image_pull_policy = "Always"
+
+          port {
+            container_port = var.wizarr.port
+          }
+
+          env {
+            name  = "DISABLE_BUILTIN_AUTH"
+            value = "false"
+          }
+          env {
+            name  = "TZ"
+            value = "Europe/Paris"
+          }
+
+          volume_mount {
+            name       = "wizarr-data"
+            mount_path = "/data"
+          }
+        }
+
+        volume {
+          name = "wizarr-data"
+          persistent_volume_claim {
+            claim_name = kubernetes_persistent_volume_claim_v1.wizarr-data.metadata[0].name
+          }
+        }
+      }
+    }
+  }
+}