variable "sonarr" {
  type = object({
    app_name  = optional(string, "sonarr")
    image     = string
    version   = optional(string, "latest")
    subdomain = optional(string, "sonarr")
    port      = optional(number, 8989)
  })
}

resource "kubernetes_service_v1" "sonarr" {
  metadata {
    name      = var.sonarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    selector = {
      app = var.sonarr.app_name
    }
    port {
      port        = var.sonarr.port
      target_port = var.sonarr.port
    }
  }
}

resource "kubernetes_ingress_v1" "sonarr" {
  metadata {
    name      = var.sonarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name

    annotations = {
      "cert-manager.io/cluster-issuer" = "letsencrypt"
    }
  }

  spec {
    tls {
      hosts       = ["${var.sonarr.subdomain}.${var.domain}"]
      secret_name = "${var.sonarr.app_name}-tls"
    }

    rule {
      host = "${var.sonarr.subdomain}.${var.domain}"
      http {
        path {
          path      = "/"
          path_type = "Prefix"
          backend {
            service {
              name = kubernetes_service_v1.sonarr.metadata[0].name
              port {
                number = var.sonarr.port
              }
            }
          }
        }
      }
    }
  }
}

resource "kubernetes_persistent_volume_claim_v1" "sonarr-config" {
  metadata {
    name      = "${var.sonarr.app_name}-config"
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    storage_class_name = "local-path"
    access_modes       = ["ReadWriteOnce"]

    resources {
      requests = {
        storage = "1Gi"
      }
    }
  }
}

resource "kubernetes_deployment_v1" "sonarr" {
  metadata {
    name      = var.sonarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name
    labels = {
      app = var.sonarr.app_name
    }
  }

  spec {
    replicas = 1
    selector {
      match_labels = {
        app = var.sonarr.app_name
      }
    }

    template {
      metadata {
        labels = {
          "app" = var.sonarr.app_name
        }
      }

      spec {
        container {
          name              = var.sonarr.app_name
          image             = "${var.sonarr.image}:${var.sonarr.version}"
          image_pull_policy = "Always"

          port {
            container_port = var.sonarr.port
          }

          env {
            name  = "PUID"
            value = 0
          }
          env {
            name  = "GUID"
            value = 0
          }

          volume_mount {
            name       = "sonarr-config"
            mount_path = "/config"
          }
          volume_mount {
            name       = "sonarr-data"
            mount_path = "/data"
          }
        }

        volume {
          name = "sonarr-config"
          persistent_volume_claim {
            claim_name = kubernetes_persistent_volume_claim_v1.sonarr-config.metadata[0].name
          }
        }
        volume {
          name = "sonarr-data"
          nfs {
            path      = var.media_storage.root_path
            server    = var.media_storage.server_ip
            read_only = false
          }
        }
      }
    }
  }
}