variable "bazarr" {
  type = object({
    app_name = optional(string, "bazarr")
    image = string
    version = optional(string, "latest")
    subdomain = optional(string, "bazarr")
    port = optional(number, 6767)
  })
}

resource "kubernetes_service_v1" "bazarr" {
  metadata {
    name = var.bazarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    selector = {
      app = var.bazarr.app_name
    }
    port {
      port = var.bazarr.port
      target_port = var.bazarr.port
    }
  }
}

resource "kubernetes_ingress_v1" "bazarr" {
  metadata {
    name = var.bazarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name

    annotations = {
      "cert-manager.io/cluster-issuer" = "letsencrypt"
    }
  }

  spec {
    tls {
      hosts = ["${var.bazarr.subdomain}.${var.domain}"]
      secret_name = "${var.bazarr.app_name}-tls"
    }

    rule {
      host = "${var.bazarr.subdomain}.${var.domain}"
      http {
        path {
          path = "/"
          path_type = "Prefix"
          backend {
            service {
              name = kubernetes_service_v1.bazarr.metadata[0].name
              port {
                number = var.bazarr.port
              }
            }
          }
        }
      }
    }
  }
}

resource "kubernetes_persistent_volume_claim_v1" "bazarr-config" {
  metadata {
    name = "${var.bazarr.app_name}-config"
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    storage_class_name = "local-path"
    access_modes = ["ReadWriteOnce"]

    resources {
      requests = {
        storage = "1Gi"
      }
    }
  }
}

resource "kubernetes_deployment_v1" "bazarr" {
 metadata {
   name = var.bazarr.app_name
   namespace = kubernetes_namespace_v1.media.metadata[0].name
   labels = {
     app = var.bazarr.app_name
   }
 }

 spec {
   replicas = 1
   selector {
     match_labels = {
       app = var.bazarr.app_name
     }
   }

   template {
     metadata {
       labels =  {
         "app" = var.bazarr.app_name
       }
     }

     spec {
       container {
         name = var.bazarr.app_name
         image = "${var.bazarr.image}:${var.bazarr.version}"
         image_pull_policy = "Always"

         port {
           container_port = var.bazarr.port
         }

         env {
           name = "PUID"
           value = 0
         }
         env {
           name = "GUID"
           value = 0
         }
         env {
           name = "TZ"
           value = "Europe/Paris"
         }

         volume_mount {
           name = "bazarr-config"
           mount_path = "/config"
         }
         volume_mount {
           name = "movies"
           mount_path = "/movies"
         }
         volume_mount {
           name = "shows"
           mount_path = "/tv"
         }
       }

       volume {
         name = "bazarr-config"
         persistent_volume_claim {
           claim_name = kubernetes_persistent_volume_claim_v1.bazarr-config.metadata[0].name
         }
       }
       volume {
         name = "movies"
         nfs {
           path = "${var.media_storage.root_path}/${var.media_storage.movies_path}"
           server = var.media_storage.server_ip
           read_only = false
         }
       }
       volume {
         name = "shows"
         nfs {
           path = "${var.media_storage.root_path}/${var.media_storage.shows_path}"
           server = var.media_storage.server_ip
           read_only = false
         }
       }
     }
   }
 }
}