variable "radarr" {
  type = object({
    app_name = optional(string, "radarr")
    image = string
    version = optional(string, "latest")
    subdomain = optional(string, "radarr")
    port = optional(number, 7878)
  })
}

resource "kubernetes_service_v1" "radarr" {
  metadata {
    name = var.radarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    selector = {
      app = var.radarr.app_name
    }
    port {
      port = var.radarr.port
      target_port = var.radarr.port
    }
  }
}

resource "kubernetes_ingress_v1" "radarr" {
  metadata {
    name = var.radarr.app_name
    namespace = kubernetes_namespace_v1.media.metadata[0].name

    annotations = {
      "cert-manager.io/cluster-issuer" = "letsencrypt"
    }
  }

  spec {
    tls {
      hosts = ["${var.radarr.subdomain}.${var.domain}"]
      secret_name = "${var.radarr.app_name}-tls"
    }

    rule {
      host = "${var.radarr.subdomain}.${var.domain}"
      http {
        path {
          path = "/"
          path_type = "Prefix"
          backend {
            service {
              name = kubernetes_service_v1.radarr.metadata[0].name
              port {
                number = var.radarr.port
              }
            }
          }
        }
      }
    }
  }
}

resource "kubernetes_persistent_volume_claim_v1" "radarr-config" {
  metadata {
    name = "${var.radarr.app_name}-config"
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    storage_class_name = "local-path"
    access_modes = ["ReadWriteOnce"]

    resources {
      requests = {
        storage = "1Gi"
      }
    }
  }
}

resource "kubernetes_deployment_v1" "radarr" {
 metadata {
   name = var.radarr.app_name
   namespace = kubernetes_namespace_v1.media.metadata[0].name
   labels = {
     app = var.radarr.app_name
   }
 }

 spec {
   replicas = 1
   selector {
     match_labels = {
       app = var.radarr.app_name
     }
   }

   template {
     metadata {
       labels =  {
         "app" = var.radarr.app_name
       }
     }

     spec {
       container {
         name = var.radarr.app_name
         image = "${var.radarr.image}:${var.radarr.version}"
         image_pull_policy = "Always"

         port {
           container_port = var.radarr.port
         }

         env {
           name = "PUID"
           value = 0
         }
         env {
           name = "GUID"
           value = 0
         }

         volume_mount {
           name = "radarr-config"
           mount_path = "/config"
         }
         volume_mount {
           name = "radarr-data"
           mount_path = "/data"
         }
       }

       volume {
         name = "radarr-config"
         persistent_volume_claim {
           claim_name = kubernetes_persistent_volume_claim_v1.radarr-config.metadata[0].name
         }
       }
       volume {
         name = "radarr-data"
         nfs {
           path = "${var.media_storage.root_path}"
           server = var.media_storage.server_ip
           read_only = false
         }
       }
     }
   }
 }
}