variable "prowlarr" {
  type = object({
    app_name = optional(string, "prowlarr")
    image = string
    version = optional(string, "latest")
    subdomain = optional(string, "prowlarr")
    port = optional(number, 9696)
  })
}

resource "kubernetes_service_v1" "prowlarr" {
  metadata {
    name = "${var.prowlarr.app_name}"
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    selector = {
      app = "${var.prowlarr.app_name}"
    }
    port {
      port = var.prowlarr.port
      target_port = var.prowlarr.port
    }
  }
}

resource "kubernetes_ingress_v1" "prowlarr" {
  metadata {
    name = "${var.prowlarr.app_name}"
    namespace = kubernetes_namespace_v1.media.metadata[0].name

    annotations = {
      "cert-manager.io/cluster-issuer" = "letsencrypt"
    }
  }

  spec {
    tls {
      hosts = ["${var.prowlarr.subdomain}.${var.domain}"]
      secret_name = "${var.prowlarr.app_name}-tls"
    }

    rule {
      host = "${var.prowlarr.subdomain}.${var.domain}"
      http {
        path {
          path = "/"
          path_type = "Prefix"
          backend {
            service {
              name = kubernetes_service_v1.prowlarr.metadata[0].name
              port {
                number = var.prowlarr.port
              }
            }
          }
        }
      }
    }
  }
}

resource "kubernetes_persistent_volume_claim_v1" "prowlarr-config" {
  metadata {
    name = "${var.prowlarr.app_name}-config"
    namespace = kubernetes_namespace_v1.media.metadata[0].name
  }

  spec {
    storage_class_name = "local-path"
    access_modes = ["ReadWriteOnce"]

    resources {
      requests = {
        storage = "1Gi"
      }
    }
  }
}

resource "kubernetes_deployment_v1" "prowlarr" {
 metadata {
   name = "${var.prowlarr.app_name}"
   namespace = kubernetes_namespace_v1.media.metadata[0].name
   labels = {
     app = "${var.prowlarr.app_name}"
   }
 }

 spec {
   replicas = 1
   selector {
     match_labels = {
       app = "${var.prowlarr.app_name}"
     }
   }

   template {
     metadata {
       labels =  {
         "app" = "${var.prowlarr.app_name}"
       }
     }

     spec {
       container {
         name = "${var.prowlarr.app_name}"
         image = "${var.prowlarr.image}:${var.prowlarr.version}"
         image_pull_policy = "Always"

         port {
           container_port = var.prowlarr.port
         }

         volume_mount {
           name = "prowlarr-config"
           mount_path = "/config"
         }
       }

       volume {
         name = "prowlarr-config"
         persistent_volume_claim {
           claim_name = kubernetes_persistent_volume_claim_v1.prowlarr-config.metadata[0].name
         }
       }
     }
   }
 }
}